🖍️Main commit

build.gradle.kts

@@ -0,0 +1,69 @@
+plugins {
+    kotlin("jvm") version "2.2.0-Beta1"
+    id("com.gradleup.shadow") version "8.3.0"
+    id("xyz.jpenilla.run-paper") version "2.3.1"
+    id("io.papermc.paperweight.userdev") version "2.0.0-beta.16"
+}
+
+group = "fr.azur"
+version = "1.0-SNAPSHOT"
+
+repositories {
+    mavenCentral()
+    gradlePluginPortal()
+    maven("https://repo.papermc.io/repository/maven-public/") {
+        name = "papermc-repo"
+    }
+    maven("https://oss.sonatype.org/content/groups/public/") {
+        name = "sonatype"
+    }
+    maven("https://repo.codemc.org/repository/maven-public/") {
+        name = "codemc"
+    }
+    maven("https://repo.plasmoverse.com/releases")
+    maven("https://repo.plasmoverse.com/snapshots")
+}
+
+dependencies {
+    paperweight.paperDevBundle("1.21.4-R0.1-SNAPSHOT")
+
+
+    compileOnly("net.skinsrestorer:skinsrestorer-api:15.6.3")
+    compileOnly("su.plo.voice.api:server:2.1.4")
+
+    implementation(kotlin("stdlib-jdk8"))
+}
+
+val targetJavaVersion = 21
+kotlin {
+    jvmToolchain(targetJavaVersion)
+}
+
+tasks {
+    runServer {
+        downloadPlugins {
+            modrinth("plasmo-voice", "spigot-2.1.4")
+            modrinth("skinsrestorer", "15.6.3")
+        }
+        minecraftVersion("1.21.4")
+    }
+    build {
+        dependsOn("shadowJar")
+    }
+    processResources {
+        val props = mapOf("version" to version)
+        inputs.properties(props)
+        filteringCharset = "UTF-8"
+        filesMatching("paper-plugin.yml") {
+            expand(props)
+        }
+    }
+    shadowJar {
+        archiveBaseName.set("tcoww")
+
+        minimize()
+
+//        exclude("META-INF/*.kotlin_module")
+//        exclude("META-INF/*.version")
+    }
+}